תקציר

תיאורF dist cdf.svg	English: The cdf of the F distribution.
תאריך יצירה	‏16 באוגוסט 2014‏, 02:01:53
מקור	נוצר על־ידי מעלה היצירה
יוצר	IkamusumeFan
גרסאות אחרות

Gnuplot Source Code

# Author: Ika
# Date: 08/16/2014

set term svg size 800,600 enhanced font 'Arial, 24'
set output 'f_cdf.svg'

set samples 500
set xrange [0:5]
set yrange [0:1]
set xtics 1
set ytics 0.5
set xzeroaxis lt -1 lc rgb "black" lw 1
set yzeroaxis lt -1 lc rgb "black" lw 1

# Draw the F distribution's cdf
set key right bottom

# Incomplete Beta function
F(x,d1,d2) = ibeta(d1/2.0,d2/2.0,d1*x/(d1*x+d2))

plot F(x, 1.0, 1.0) t "d1=1, d2=1" lc rgb "red" lw 5,\
   F(x, 2.0, 1.0) t "d1=2, d2=1" lc rgb "black" lw 5,\
   F(x, 5.0, 2.0) t "d1=5, d2=2" lc rgb "blue" lw 5,\
   F(x,10.0, 1.0) t "d1=10, d2=1" lc rgb "green" lw 5,\
   F(x,100.0, 100.0) t "d1=100, d2=100" lc rgb "grey" lw 5

set term x11
set output

רישיון

אני, בעל זכויות היוצרים על עבודה זו, מפרסם בזאת את העבודה תחת הרישיון הבא:

הקובץ הזה מתפרסם לפי תנאי רישיון קריאייטיב קומונז ייחוס-שיתוף זהה 4.0 בין־לאומי.

הנכם רשאים:

• לשתף – להעתיק, להפיץ ולהעביר את העבודה
• לערבב בין עבודות – להתאים את העבודה

תחת התנאים הבאים:

• ייחוס – יש לתת ייחוס הולם, לתת קישור לרישיון, ולציין אם נעשו שינויים. אפשר לעשות את זה בכל צורה סבירה, אבל לא בשום צורה שמשתמע ממנה שמעניק הרישיון תומך בך או בשימוש שלך.
• שיתוף זהה – אם תיצרו רמיקס, תשנו, או תבנו על החומר, חובה עליכם להפיץ את התרומות שלך לפי תנאי רישיון זהה או תואם למקור.

https://creativecommons.org/licenses/by-sa/4.0CC BY-SA 4.0 Creative Commons Attribution-Share Alike 4.0 truetrue