#download csv from http://www.bundesbank.de/statistik/statistik_zeitreihen.php?lang=de&open=devisen&func=list&tr=www_s332_b01011_2

#replace decimal separator , with . and remove comments
! perl -ne "s/,/./g; /^[0-9]/ || next; print; " bbk_paket1.csv > bbk_paket2.csv



#input
set timefmt "%Y-%m"
set datafile missing '.'
set datafile separator ';'


#output
set key top left
set style data lines
set grid

set xdata time
#set xlabel 'Date'
set xtics 157680000
set mxtics 5
set format x '%Y'

set ylabel 'ATS'
set format y '%.2f'

## gnuplot for SVG - gnuplot 4.2 / Ubuntu 8.10 
set term svg size 800,600 font "Arial,10"

set outp 'DEM to ATS.svg'
set style line 1 lt rgb 'blue' lw 1

#available currencies:
#$2    * WU5017: Devisenkurse der Frankfurter Börse / 1 IEP = ... DM / Irland
#$4    * WU5016: Devisenkurse der Frankfurter Börse / 100 CHF = ... DM / Schweiz
#$6    * WU5015: Devisenkurse der Frankfurter Börse / 100 ATS = ... DM / Österreich
#$8    * WU5014: Devisenkurse der Frankfurter Börse / 100 JPY = ... DM / Japan
#$10    * WU5013: Devisenkurse der Frankfurter Börse / 100 SEK = ... DM / Schweden
#$12    * WU5012: Devisenkurse der Frankfurter Börse / 100 FRF = ... DM / ab 1960 / Frankreich
#$14    * WU5011: Devisenkurse der Frankfurter Börse / 100 ffrs = ... DM / bis Ende 1959 / Frankreich
#$16    * WU5010: Devisenkurse der Frankfurter Börse / 100 NOK = ... DM / Norwegen
#$18    * WU5009: Devisenkurse der Frankfurter Börse / 1 USD = ... DM / Vereinigte Staaten
#$20    * WU5008: Devisenkurse der Frankfurter Börse / 1 CAD = ... DM / Kanada
#$22    * WU5006: Devisenkurse der Frankfurter Börse / 100 ESP = ... DM / Spanien
#$24    * WU5007: Devisenkurse der Frankfurter Börse / 1000 ITL = ... DM / Italien
#$26    * WU5005: Devisenkurse der Frankfurter Börse / 1 GBP = ... DM / Vereinigtes Königreich
#$28    * WU5004: Devisenkurse der Frankfurter Börse / 100 PTE = ... DM / Portugal
#$30    * WU5003: Devisenkurse der Frankfurter Börse / 100 DKK = ... DM / Dänemark
#$32    * WU5002: Devisenkurse der Frankfurter Börse / 100 FIM = ... DM / Finnland
#$34    * WU5001: Devisenkurse der Frankfurter Börse / 100 BEF = ... DM / Belgien
#$36    * WU5000: Devisenkurse der Frankfurter Börse / 100 NLG = ... DM / Niederlande

plot 'bbk_paket2.csv' usi 1:(1/($6/100)) title '1 DEM in ATS' ls 1