#include "colors.inc"

light_source { <1500,2500,-2500> color White shadowless }

camera {
	angle 32
    location <0, -1 ,-13.0>
    look_at  <0, -0.1, 0>
    up    <0, 1, 0>
    right   <1, 0, 0>
}

// define vertices
#macro V(a1,a2,a3)
	sphere{ <a1,a2,a3>, 0.1 pigment{color rgb<1,0.8,0.65>*0.05} }
#end
// define thin edges
#macro E1( a1,a2,a3, b1,b2,b3 )
	cylinder{ <a1,a2,a3>, <b1,b2,b3>, 0.02 pigment{color rgb<1,0.8,0.65>*0.3} }
#end
// define thick edges
#declare StrongEdgeColor = rgb<1,0.8,0.65>*0.15;
#macro E2( a,b,c,d )
	cylinder{ a, b, 0.04 pigment{color StrongEdgeColor} }
	cylinder{ b, c, 0.04 pigment{color StrongEdgeColor} }
	cylinder{ c, d, 0.04 pigment{color StrongEdgeColor} }
	cylinder{ d, a, 0.04 pigment{color StrongEdgeColor} }
#end

union {

    // faces
    union{
        polygon{ 6, <0,0,0> <2,0,0> <3,0,1> <3,0,3> <1,0,3> <0,0,2> }
        polygon{ 6, <0,0,0> <2,0,0> <3,1,0> <3,3,0> <1,3,0> <0,2,0> }
        polygon{ 6, <0,0,0> <0,2,0> <0,3,1> <0,3,3> <0,1,3> <0,0,2> }
        polygon{ 6, <4,4,4> <4,2,4> <3,1,4> <1,1,4> <1,3,4> <2,4,4> }
        polygon{ 6, <4,4,4> <2,4,4> <1,4,3> <1,4,1> <3,4,1> <4,4,2> }
        polygon{ 6, <4,4,4> <4,4,2> <4,3,1> <4,1,1> <4,1,3> <4,2,4> }

        polygon{ 4, <2,0,0> <3,1,0> <4,1,1> <3,0,1> }
        polygon{ 4, <0,2,0> <1,3,0> <1,4,1> <0,3,1> }
        polygon{ 4, <0,0,2> <1,0,3> <1,1,4> <0,1,3> }
        polygon{ 4, <3,3,0> <4,3,1> <4,4,2> <3,4,1> }
        polygon{ 4, <3,0,3> <4,1,3> <4,2,4> <3,1,4> }
        polygon{ 4, <0,3,3> <1,4,3> <2,4,4> <1,3,4> }

        polygon{ 4, <3,1,0> <3,3,0> <4,3,1> <4,1,1> }
        polygon{ 4, <4,1,1> <4,1,3> <3,0,3> <3,0,1> }
        polygon{ 4, <1,3,0> <3,3,0> <3,4,1> <1,4,1> }
        polygon{ 4, <0,3,1> <0,3,3> <1,4,3> <1,4,1> }
        polygon{ 4, <1,0,3> <3,0,3> <3,1,4> <1,1,4> }
        polygon{ 4, <0,1,3> <0,3,3> <1,3,4> <1,1,4> }

        texture {
            pigment{ color rgbt<1,0.8,0.65,0.2> }
            finish { diffuse 0.6 phong 0.5 reflection 0 }
        }
    }

    //put vertices
	V(0,0,0) V(0,2,0) V(1,3,0) V(2,0,0) V(3,1,0) V(3,3,0)
	V(0,3,1) V(1,4,1) V(3,0,1) V(3,4,1) V(4,1,1) V(4,3,1)
	V(0,0,2) V(4,4,2)
	V(0,1,3) V(0,3,3) V(1,0,3) V(1,4,3) V(3,0,3) V(4,1,3)
	V(1,1,4) V(1,3,4) V(2,4,4) V(3,1,4) V(4,2,4) V(4,4,4)
    // put thin edges
	E1( 0,0,0, 2,0,0 ) E1( 1,3,0, 3,3,0 ) E1( 1,4,1, 3,4,1 ) E1( 1,0,3, 3,0,3 ) E1( 1,1,4, 3,1,4 ) E1( 2,4,4, 4,4,4 )
	E1( 0,0,0, 0,0,2 ) E1( 3,0,1, 3,0,3 ) E1( 4,1,1, 4,1,3 ) E1( 0,3,1, 0,3,3 ) E1( 1,4,1, 1,4,3 ) E1( 4,4,2, 4,4,4 )
	E1( 0,0,0, 0,2,0 ) E1( 3,1,0, 3,3,0 ) E1( 4,1,1, 4,3,1 ) E1( 0,1,3, 0,3,3 ) E1( 1,1,4, 1,3,4 ) E1( 4,2,4, 4,4,4 )
    // put thick edges
	E2( <2,0,0>, <3,0,1>, <4,1,1>, <3,1,0> ) E2( <0,2,0>, <0,3,1>, <1,4,1>, <1,3,0> ) E2( <0,0,2>, <0,1,3>, <1,1,4>, <1,0,3> )
	E2( <4,4,2>, <4,3,1>, <3,3,0>, <3,4,1> ) E2( <4,2,4>, <4,1,3>, <3,0,3>, <3,1,4> ) E2( <2,4,4>, <1,4,3>, <0,3,3>, <1,3,4> )

	translate<-2,-2,-2>
    rotate 45*z
    rotate -35*x
    rotate 120*y

}